Microsoft Small Basic Program Listing

' Igo03.smallbasic - Igo v0.3
'
' 履歴：
' v0.1 2010/07/21 初版：碁盤の表示 (243行 NBK992)
' v0.2 2010/07/23 手数の表示 (265行 JVR185)
' v0.3 2010/07/24 人による次の手の処理 (378行)
'
' work: boolean bProgramEnd - プログラム終了
' work: boolean bGameEnd - 終局
' work: integer iMove - 手数
'
' プログラムの初期化
InitProgram()
' 対戦者名（または棋譜名）の入力
InputGameInfo()
' プログラム終了が指定されるまで｛｝内繰り返し
While (bProgramEnd = "False")
'｛
'　盤の初期化
InitBoard()
'　棋譜の初期化
InitRecord()
'　盤の表示
ShowBoard()
iMove = 0
'　終局になるまで｛｝内繰り返し
While (bGameEnd = "False")
'　｛
iMove = iMove + 1
'　　着手可能な手を調べる
GetPutList()
'　　先手が打つ
If (bReplay) Then
Replay()
Else
Human()
EndIf
'　　禁じ手なら再度打つ
'　　棋譜の記録
If (bReplay = "False") Then
Record()
EndIf
'　　盤の表示
DrawStone()
Sound.PlayClickAndWait()
'　　終局の判定
Judge()
If bGameEnd Then
Goto lGameEnd
EndIf
'
iMove = iMove + 1
'　　着手可能な手を調べる
GetPutList()
'　　後手が打つ
If (bReplay) Then
Replay()
Else
Human()
EndIf
'　　禁じ手なら再度打つ
'　　棋譜の記録
If (bReplay = "False") Then
Record()
EndIf
'　　盤の表示
DrawStone()
Sound.PlayClickAndWait()
'　　終局の判定
Judge()
'　｝
EndWhile
lGameEnd:
'　対戦者名（または棋譜名）の入力
InputGameInfo()
bProgramEnd = "True"
' ｝
EndWhile
'
' プログラムの初期化
' out: constant SPACE - 空点
' out: constant BLACK - 黒
' out: constant WHITE - 白
' out: constant OB - 盤外
' out: integer iRo - 何路か
' out: real rCX - 文字幅
' out: real rCY - 文字の高さ
' out: integer iMove - 手数
' out: string sBoardColor - 碁盤の色
Sub InitProgram
SPACE = 0 ' 空点
BLACK = 1 ' 黒
WHITE = 2 ' 白
OB = 3 ' 盤外
iRo = 6
rCX = 15.6
rCY = 24
GraphicsWindow.FontSize = rCY
sBoardColor = "Wheat"
EndSub
'
' 対戦者名（または棋譜名）の入力
' out: boolean bShowMove - 手数を表示する
' out: boolean bGameEnd - 終局
' out: boolean bProgramEnd - プログラム終了
' out: boolean bReplay - 再生モード
Sub InputGameInfo
bShowMove = "True"
bGameEnd = "False"
bProgramEnd = "False"
bReplay = "False"
Program.Delay(2000)
EndSub
'
' 盤の初期化
' in: integer iRo - 何路か
' in: real rCX - 文字幅
' in: real rCY - 文字の高さ
' work: integer i, iX, iY
' out: integer iBoard[][] - 碁盤
' out: integer idLX, idLY - 線の間隔
' out: integer iSR - 碁石の半径
' out: integer iLX0, iLY0, iLX1, iLY1 - 左端, 上端, 右端, 下端の線
' out: integer iBX0, iBY0, iBX1, iBY1 - 盤の左端, 上端, 右端, 下端
' out: integer iHama[] - アゲハマ
Sub InitBoard
For i = 0 To iRo + 1
iBoard[0][i] = OB
iBoard[iRo + 1][i] = OB
iBoard[i][0] = OB
iBoard[i][iRo + 1] = OB
EndFor
For iX = 1 To iRo
For iY = 1 To iRo
iBoard[iX][iY] = SPACE
EndFor
EndFor
idLX = rCX * 3 ' 線の間隔
iSR = idLX / 2 - 2　' 碁石の半径
idLY = rCY * 2 ' 線の間隔
iLX0 = rCX * 6.5 ' 左端の線
iLY0 = rCY * 4.5 ' 上端の線
iLX1 = iLX0 + idLX * (iRo - 1) ' 右端の線
iLY1 = iLY0 + idLY * (iRo - 1) ' 下端の線
iBX0 = iLX0 - idLX * 1.5 ' 盤の左端
iBY0 = iLY0 - idLY * 1.5 ' 盤の上端
iBX1 = iLX1 + idLX ' 盤の右端
iBY1 = iLY1 + idLY ' 盤の下端
iHama[BLACK] = 0
iHama[WHITE] = 0
EndSub
'
' 盤の表示
' in: integer idLX, idLY - 線の間隔
' in: integer iSR - 碁石の半径
' in: integer iLX0, iLY0, iLX1, iLY1 - 左端, 上端, 右端, 下端の線
' in: integer iBX0, iBY0, iBX1, iBY1 - 盤の左端, 上端, 右端, 下端
' work: integer iX, iY
Sub ShowBoard
' 盤の色を塗る
GraphicsWindow.BrushColor = sBoardColor
GraphicsWindow.FillRectangle(iBX0, iBY0, iBX1 - iBX0, iBY1 - iBY0)
' 線を描く
GraphicsWindow.PenColor = "Black"
For iX = iLX0 To iLX1 Step idLX
GraphicsWindow.DrawLine(iX, iLY0, iX, iLY1)
EndFor
For iY = iLY0 To iLY1 Step idLY
GraphicsWindow.DrawLine(iLX0, iY, iLX1, iY)
EndFor
' 数字を書く
GraphicsWindow.BrushColor = "Black"
For iX = 1 To iRo
GraphicsWindow.DrawText(iLX0 + (iX - 1.2) * idLX, iLY0 - idLY - 3, iX)
EndFor
For iY = 1 To iRo
GraphicsWindow.DrawText(iLX0 - idLX, iLY0 + (iY - 1.25) * idLY - 3, iY)
EndFor
EndSub
'
' 碁石を描く
' in: integer iX, iY - 碁石の座標
' in: integer iColor - 碁石の色
' in: boolean bShowMove - 手数を表示する
' in: integer iMove - 手数
' in: integer iLX0 - 左端の縦線のX座標
' in: integer iLY0 - 上端の横線のY座標
' in: integer idLX - 縦線の間隔
' in: integer idLY - 横線の間隔
' in: integer iSR - 碁石の半径
' work: integer iNX, iNY - 手数の座標
' work: integer iND - 手数の桁数
Sub DrawStone
If iColor = WHITE Then
GraphicsWindow.BrushColor = "White"
GraphicsWindow.FillEllipse(iLX0 + (iX - 1) * idLX - iSR, iLY0 + (iY - 1) * idLY - iSR, iSR * 2, iSR * 2)
If bShowMove Then
GraphicsWindow.BrushColor = "Black"
If iMove > 9 Then
iND = 2
Else
iND = 1
EndIf
iNX = iLX0 + (iX - 1) * idLX - rCX / (3 - iND)
iNY = iLY0 + (iY - 1) * idLY - rCY / 2 - 3
GraphicsWindow.DrawText(iNX, iNY, iMove)
EndIf
ElseIf iColor = BLACK Then
GraphicsWindow.BrushColor = "Black"
GraphicsWindow.FillEllipse(iLX0 + (iX - 1) * idLX - iSR, iLY0 + (iY - 1) * idLY - iSR, iSR * 2, iSR * 2)
If bShowMove Then
GraphicsWindow.BrushColor = "White"
If iMove > 9 Then
iND = 2
Else
iND = 1
EndIf
iNX = iLX0 + (iX - 1) * idLX - rCX / (3 - iND)
iNY = iLY0 + (iY - 1) * idLY - rCY / 2 - 3
GraphicsWindow.DrawText(iNX, iNY, iMove)
EndIf
EndIf
EndSub
'
' 碁石を消す
' in: integer iX, iY - 碁石の座標
' work: integer iEX0, iEY0, iEX1, iEY1 - 書きなおす線の座標
Sub EraseStone
' 碁石を碁盤の色で消す
GraphicsWindow.BrushColor = sBoardColor
GraphicsWindow.FillRectangle(iLX0 + (iX - 1) * idLX - iSR, iLY0 + (iY - 1) * idLY - iSR, iSR * 2, iSR * 2)
GraphicsWindow.PenColor = "Black"
' 横線の引き直し
If iX = 1 Then
iEX0 = iLX0
Else
iEX0 = iLX0 + (iX - 1) * idLX - iSR
EndIf
If iX = iRo Then
iEX1 = iLX0 + (iX - 1) * idLX
Else
iEX1 = iLX0 + (iX - 1) * idLX + iSR
EndIf
iEY0 = iLY0 + (iY - 1) * idLY
iEY1 = iLY0 + (iY - 1) * idLY
GraphicsWindow.DrawLine(iEX0, iEY0, iEX1, iEY1)
' 縦線の引き直し
iEX0 = iLX0 + (iX - 1) * idLX
iEX1 = iLX0 + (iX - 1) * idLX
If iY = 1 Then
iEY0 = iLY0
Else
iEY0 = iLY0 + (iY - 1) * idLY - iSR
EndIf
If iY = iRo Then
iEY1 = iLY0 + (iY - 1) * idLY
Else
iEY1 = iLY0 + (iY - 1) * idLY + iSR
EndIf
GraphicsWindow.DrawLine(iEX0, iEY0, iEX1, iEY1)
EndSub
'
' 棋譜の初期化
' out: integer iNumRec - 棋譜の手数
Sub InitRecord
iNumRec = 0
EndSub
'
' 棋譜の記録
' in: integer iX, iY - 次の手(碁盤の座標)
' in: integer iColor - 碁石の色
' out: integer iRecord[][] - 棋譜
' out: integer iNumRec - 棋譜の手数
Sub Record
iNumRec = iNumRec + 1
iRecord[iNumRec]["x"] = iX
iRecord[iNumRec]["y"] = iY
iRecord[iNumRec]["turn"] = iColor
EndSub
'
' 着手可能な手のリスト作成
' in: integer iboard[][] - 碁盤
' out: integer iPossible - 着手可能な手の数
' out: integer iPX[], iPX[] - 着手可能な手
' work: integer i - iBoard[][]の座標 x, yの代わり
Sub GetPutList
iPossible = 0
For i = 0 To iRo * iRo - 1
If iBoard[Math.Remainder(i, iRo) + 1][Math.Floor(i / iRo) + 1] = SPACE Then
iPossible = iPossible + 1
iPX[iPossible] = Math.Remainder(i, iRo) + 1
iPY[iPossible] = Math.Floor(i / iRo) + 1
EndIf
EndFor
EndSub
'
' 次の手を打つ - Human (人)
' in: integer iPossible - 着手可能な手
' in: integer iMove - 手数
' work: i - 着手可能な手の添字
' work: integer iMX, iMY - マウス座標
' work: boolean bNotClicked - マウスがクリックされていない
' out: iX, iY - 次の手(碁盤の座標)
' out: iColor - 碁石の色
' out: iBoard[][] - 碁盤
' out: iHama[] - アゲハマ
Sub Human
GraphicsWindow.MouseDown = OnMouseDown
While "True"
bNotClicked = "True"
While bNotClicked
Program.delay(100)
EndWhile
GetPosition()
For i = 1 To iPossible
If iPX[i] = iX And iPY[i] = iY Then
Goto lPossiblePut
EndIf
EndFor
' 碁石を取り除く
iHama[2 - iBoard[iX][iY]] = iHama[2 - iBoard[iX][iY]] + 1
iBoard[iX][iY] = SPACE
EraseStone()
EndWhile
lPossiblePut:
iColor = Math.Remainder((iMove - 1), 2) + 1
iBoard[iX][iY] = iColor
EndSub
'
' マウスが押されたときの処理
' out: integer iMX, iMY - マウス座標
' out: boolean bNotClicked - マウスがクリックされていない
Sub OnMouseDown
iMX = GraphicsWindow.MouseX
iMY = GraphicsWindow.MouseY
bNotClicked = "False"
EndSub
'
' マウスをクリックした座標から碁盤の座標を得る
' in: integer iMX, iMY - マウス座標
' out: integer iX, iY - 碁盤の座標
Sub GetPosition
iX = Math.Floor((iMX - iLX0 + idLX / 2) / idLX) + 1
iY = Math.Floor((iMY - iLY0 + idLY / 2) / idLY) + 1
If iX < 1 Then
iX = 1
EndIf
If iY < 1 Then
iY = 1
EndIf
If iX > iRo Then
iX = iRo
EndIf
If iY > iRo Then
iY = iRo
EndIf
EndSub
'
' 次の手を打つ - Replay (棋譜の再生)
' in: integer iMove - 手番
' in: integer iRecord - 棋譜
' out: integer iX, iY - 次の手(碁盤の座標)
' out: integer iColor - 碁石の色
' out: integer iBoard[][] - 碁盤
Sub Replay
iX = iRecord[iMove]["x"]
iY = iRecord[iMove]["y"]
iColor = iRecord[iMove]["turn"]
iBoard[iX][iY] = iColor
EndSub
'
' 棋譜の記録
'
' 終局の判定
' out: boolean bGameEnd - 終局
Sub Judge
bGameEnd = "False"
EndSub